Fix missing SDL cmake files

2025-09-23 06:53:43 +00:00 · 2024-08-06 23:37:20 -04:00
parent fa1455f4f4
commit d750ffae65
6 changed files with 1670 additions and 0 deletions
--- a/.gitignore
+++ b/.gitignore
@@ -40,6 +40,7 @@ ReleasePackageInstaller/AerofoilPackageDefs.wxi
 ReleasePackageInstaller/AerofoilPackageVersion.wxi
 packages/*
 !SDL2-2.30.5/lib/x64/*
+!SDL2-2.30.5/cmake/*.cmake
 CMakeCache.txt
 CMakeFiles/*
 Makefile
--- a/SDL2-2.30.5/cmake/CheckCPUArchitecture.cmake
+++ b/SDL2-2.30.5/cmake/CheckCPUArchitecture.cmake
@@ -0,0 +1,42 @@
+include(CheckCSourceCompiles)
+include(CMakePushCheckState)
+
+function(_internal_check_cpu_architecture macro_check NAME VARIABLE)
+  cmake_push_check_state(RESET)
+  string(TOUPPER "${NAME}" UPPER_NAME)
+  set(CACHE_VARIABLE "CHECK_CPU_ARCHITECTURE_${UPPER_NAME}")
+  set(test_src "
+int main(int argc, char *argv[]) {
+#if ${macro_check}
+  return 0;
+#else
+  choke
+#endif
+}
+")
+  check_c_source_compiles("${test_src}" "${CACHE_VARIABLE}")
+  cmake_pop_check_state()
+  if(${CACHE_VARIABLE})
+    set(${VARIABLE} "TRUE" PARENT_SCOPE)
+  else()
+    set(${VARIABLE} "FALSE" PARENT_SCOPE)
+  endif()
+endfunction()
+
+function(check_cpu_architecture ARCH VARIABLE)
+  if(ARCH STREQUAL "x86")
+    _internal_check_cpu_architecture("defined(__i386__) || defined(__i486__) || defined(__i586__) || defined(__i686__) ||defined( __i386) || defined(_M_IX86)" x86 ${VARIABLE})
+  elseif(ARCH STREQUAL "x64")
+    _internal_check_cpu_architecture("defined(__amd64__) || defined(__amd64) || defined(__x86_64__) || defined(__x86_64) || defined(_M_X64) || defined(_M_AMD64)" x64 ${VARIABLE})
+  elseif(ARCH STREQUAL "arm32")
+    _internal_check_cpu_architecture("defined(__arm__) || defined(_M_ARM)" arm32 ${VARIABLE})
+  elseif(ARCH STREQUAL "arm64")
+    _internal_check_cpu_architecture("defined(__aarch64__) || defined(_M_ARM64)" arm64 ${VARIABLE})
+  elseif(ARCH STREQUAL "loongarch64")
+    _internal_check_cpu_architecture("defined(__loongarch64)" loongarch64 ${VARIABLE})
+  else()
+    message(WARNING "Unknown CPU architectures (${ARCH}).")
+    set(${VARIABLE} FALSE)
+  endif()
+  set("${VARIABLE}" "${${VARIABLE}}" PARENT_SCOPE)
+endfunction()
--- a/SDL2-2.30.5/cmake/macros.cmake
+++ b/SDL2-2.30.5/cmake/macros.cmake
@@ -0,0 +1,148 @@
+macro(ADD_TO_ALLOPTIONS _NEWNAME)
+  list(APPEND ALLOPTIONS ${_NEWNAME})
+  string(LENGTH ${_NEWNAME} _SLEN)
+  if(${LONGESTOPTIONNAME} LESS ${_SLEN})
+    set(LONGESTOPTIONNAME ${_SLEN})
+  endif()
+endmacro()
+
+macro(SET_OPTION _NAME _DESC)
+  add_to_alloptions(${_NAME})
+  if(${ARGC} EQUAL 3)
+    set(_DEFLT ${ARGV2})
+  else()
+    set(_DEFLT OFF)
+  endif()
+  option(${_NAME} ${_DESC} ${_DEFLT})
+endmacro()
+
+macro(DEP_OPTION _NAME _DESC _DEFLT _DEPTEST _FAILDFLT)
+  add_to_alloptions("${_NAME}")
+  cmake_dependent_option("${_NAME}" "${_DESC}" "${_DEFLT}" "${_DEPTEST}" "${_FAILDFLT}")
+endmacro()
+
+macro(OPTION_STRING _NAME _DESC _VALUE)
+  add_to_alloptions(${_NAME})
+  set(${_NAME} ${_VALUE} CACHE STRING "${_DESC}")
+  set(HAVE_${_NAME} ${_VALUE})
+ENDMACRO()
+
+# Message Output
+macro(MESSAGE_WARN _TEXT)
+  message(WARNING "${_TEXT}")
+endmacro()
+
+macro(MESSAGE_ERROR _TEXT)
+  message(FATAL_ERROR "*** ERROR: ${_TEXT}")
+endmacro()
+
+macro(MESSAGE_BOOL_OPTION _NAME _VALUE)
+  if(${_VALUE})
+    message(STATUS "  ${_NAME}:\tON")
+  else()
+    message(STATUS "  ${_NAME}:\tOFF")
+  endif()
+endmacro()
+
+macro(MESSAGE_TESTED_OPTION _NAME)
+  set(_REQVALUE ${${_NAME}})
+  set(_PAD " ")
+  if(${ARGC} EQUAL 2)
+    set(_PAD ${ARGV1})
+  endif()
+  string(SUBSTRING "${_NAME}" 0 4 _NAMESTART)
+  if(_NAMESTART STREQUAL "SDL_")
+    string(SUBSTRING "${_NAME}" 4 -1 _STRIPPEDNAME)
+  else()
+    set(_STRIPPEDNAME "${_NAME}")
+  endif()
+  if(NOT HAVE_${_STRIPPEDNAME})
+    set(HAVE_${_STRIPPEDNAME} OFF)
+  elseif("${HAVE_${_STRIPPEDNAME}}" MATCHES "1|TRUE|YES|Y")
+    set(HAVE_${_STRIPPEDNAME} ON)
+  endif()
+  message(STATUS "  ${_NAME}${_PAD}(Wanted: ${_REQVALUE}): ${HAVE_${_STRIPPEDNAME}}")
+endmacro()
+
+function(LISTTOSTR _LIST _OUTPUT)
+  if(${ARGC} EQUAL 3)
+    # prefix for each element
+    set(_LPREFIX ${ARGV2})
+  else()
+    set(_LPREFIX "")
+  endif()
+  # Do not use string(REPLACE ";" " ") here to avoid messing up list
+  # entries
+  set(res)
+  foreach(_ITEM ${${_LIST}})
+    set(res "${res} ${_LPREFIX}${_ITEM}")
+  endforeach()
+  set(${_OUTPUT} "${res}" PARENT_SCOPE)
+endfunction()
+
+macro(LISTTOSTRREV _LIST _OUTPUT)
+  if(${ARGC} EQUAL 3)
+    # prefix for each element
+    set(_LPREFIX ${ARGV2})
+  else()
+    set(_LPREFIX "")
+  endif()
+  # Do not use string(REPLACE ";" " ") here to avoid messing up list
+  # entries
+  foreach(_ITEM ${${_LIST}})
+    set(${_OUTPUT} "${_LPREFIX}${_ITEM} ${${_OUTPUT}}")
+  endforeach()
+endmacro()
+
+if(CMAKE_VERSION VERSION_LESS 3.16.0 OR SDL2_SUBPROJECT)
+  # - CMake versions <3.16 do not support the OBJC language
+  # - When SDL is built as a subproject and when the main project does not enable OBJC,
+  #   CMake fails due to missing internal CMake variables (CMAKE_OBJC_COMPILE_OBJECT)
+  #   (reproduced with CMake 3.24.2)
+  macro(CHECK_OBJC_SOURCE_COMPILES SOURCE VAR)
+    set(PREV_REQUIRED_DEFS "${CMAKE_REQUIRED_DEFINITIONS}")
+    set(CMAKE_REQUIRED_DEFINITIONS "-x objective-c ${PREV_REQUIRED_DEFS}")
+    CHECK_C_SOURCE_COMPILES("${SOURCE}" ${VAR})
+    set(CMAKE_REQUIRED_DEFINITIONS "${PREV_REQUIRED_DEFS}")
+  endmacro()
+else()
+  include(CheckOBJCSourceCompiles)
+  if (APPLE)
+      enable_language(OBJC)
+  endif()
+endif()
+
+if(APPLE)
+  check_language(OBJC)
+  if(NOT CMAKE_OBJC_COMPILER)
+    message(WARNING "Cannot find working OBJC compiler.")
+  endif()
+endif()
+
+if(CMAKE_VERSION VERSION_LESS 3.13.0)
+  macro(target_link_directories _TARGET _SCOPE)
+    link_directories(${ARGN})
+  endmacro()
+endif()
+
+# CMP0087: install(CODE) and install(SCRIPT) support generator expressions.
+if(POLICY CMP0087)
+  cmake_policy(SET CMP0087 NEW)
+endif()
+function(SDL_install_pdb TARGET DIRECTORY)
+  get_property(type TARGET ${TARGET} PROPERTY TYPE)
+  if(type MATCHES "^(SHARED_LIBRARY|EXECUTABLE)$")
+    if(NOT CMAKE_VERSION VERSION_LESS 3.1)
+      install(FILES $<TARGET_PDB_FILE:${TARGET}> DESTINATION "${DIRECTORY}" OPTIONAL)
+    endif()
+  elseif(type STREQUAL "STATIC_LIBRARY")
+    if(NOT CMAKE_VERSION VERSION_LESS 3.15)
+      # FIXME: Use $<TARGET_COMPILE_PDB_FILE:${TARGET} once it becomes available (https://gitlab.kitware.com/cmake/cmake/-/issues/25244)
+      if(CMAKE_GENERATOR MATCHES "^Visual Studio.*")
+        install(CODE "file(INSTALL DESTINATION \"\${CMAKE_INSTALL_PREFIX}/${DIRECTORY}\" TYPE FILE OPTIONAL FILES \"${CMAKE_CURRENT_BINARY_DIR}/\${CMAKE_INSTALL_CONFIG_NAME}/${TARGET}.pdb\")")
+      else()
+        install(CODE "file(INSTALL DESTINATION \"\${CMAKE_INSTALL_PREFIX}/${DIRECTORY}\" TYPE FILE OPTIONAL FILES \"${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/${TARGET}.dir/${TARGET}.pdb\")")
+      endif()
+    endif()
+  endif()
+endfunction()
--- a/SDL2-2.30.5/cmake/sdlchecks.cmake
+++ b/SDL2-2.30.5/cmake/sdlchecks.cmake
--- a/SDL2-2.30.5/cmake/sdlfind.cmake
+++ b/SDL2-2.30.5/cmake/sdlfind.cmake
@@ -0,0 +1,9 @@
+
+macro(sdlFindALSA)
+  find_package(ALSA MODULE)
+  if(ALSA_FOUND AND (NOT TARGET ALSA::ALSA) )
+    add_Library(ALSA::ALSA UNKNOWN IMPORTED)
+    set_property(TARGET ALSA::ALSA PROPERTY INTERFACE_INCLUDE_DIRECTORIES ${ALSA_INCLUDE_DIRS})
+    set_property(TARGET ALSA::ALSA APPEND PROPERTY IMPORTED_LOCATION ${ALSA_LIBRARY})
+  endif()
+endmacro()
--- a/SDL2-2.30.5/cmake/sdlplatform.cmake
+++ b/SDL2-2.30.5/cmake/sdlplatform.cmake
@@ -0,0 +1,59 @@
+macro(SDL_DetectCMakePlatform)
+  set(SDL_CMAKE_PLATFORM )
+  # Get the platform
+  if(WIN32)
+    set(SDL_CMAKE_PLATFORM WINDOWS)
+  elseif(UNIX AND NOT APPLE)
+    if(CMAKE_SYSTEM_NAME MATCHES ".*Linux")
+      set(SDL_CMAKE_PLATFORM LINUX)
+    elseif(CMAKE_SYSTEM_NAME MATCHES "kFreeBSD.*")
+      set(SDL_CMAKE_PLATFORM FREEBSD)
+    elseif(CMAKE_SYSTEM_NAME MATCHES "kNetBSD.*|NetBSD.*")
+      set(SDL_CMAKE_PLATFORM NETBSD)
+    elseif(CMAKE_SYSTEM_NAME MATCHES "kOpenBSD.*|OpenBSD.*")
+      set(SDL_CMAKE_PLATFORM OPENBSD)
+    elseif(CMAKE_SYSTEM_NAME MATCHES ".*GNU.*")
+      set(SDL_CMAKE_PLATFORM GNU)
+    elseif(CMAKE_SYSTEM_NAME MATCHES ".*BSDI.*")
+      set(SDL_CMAKE_PLATFORM BSDI)
+    elseif(CMAKE_SYSTEM_NAME MATCHES "DragonFly.*|FreeBSD")
+      set(SDL_CMAKE_PLATFORM FREEBSD)
+    elseif(CMAKE_SYSTEM_NAME MATCHES "SYSV5.*")
+      set(SDL_CMAKE_PLATFORM SYSV5)
+    elseif(CMAKE_SYSTEM_NAME MATCHES "Solaris.*|SunOS.*")
+      set(SDL_CMAKE_PLATFORM SOLARIS)
+    elseif(CMAKE_SYSTEM_NAME MATCHES "HP-UX.*")
+      set(SDL_CMAKE_PLATFORM HPUX)
+    elseif(CMAKE_SYSTEM_NAME MATCHES "AIX.*")
+      set(SDL_CMAKE_PLATFORM AIX)
+    elseif(CMAKE_SYSTEM_NAME MATCHES "Minix.*")
+      set(SDL_CMAKE_PLATFORM MINIX)
+    elseif(CMAKE_SYSTEM_NAME MATCHES "QNX")
+      set(SDL_CMAKE_PLATFORM QNX)
+    endif()
+  elseif(APPLE)
+    if(CMAKE_SYSTEM_NAME MATCHES ".*Darwin.*")
+      set(SDL_CMAKE_PLATFORM DARWIN)
+    elseif(CMAKE_SYSTEM_NAME MATCHES ".*MacOS.*")
+      set(SDL_CMAKE_PLATFORM MACOSX)
+    elseif(CMAKE_SYSTEM_NAME MATCHES ".*tvOS.*")
+      set(SDL_CMAKE_PLATFORM TVOS)
+    elseif(CMAKE_SYSTEM_NAME MATCHES ".*iOS.*")
+      # !!! FIXME: remove the version check when we start requiring >= 3.14.0
+      if(CMAKE_VERSION VERSION_LESS 3.14)
+        set(SDL_CMAKE_PLATFORM IOS)
+      endif()
+    endif()
+  elseif(CMAKE_SYSTEM_NAME MATCHES "BeOS.*")
+    message_error("BeOS support has been removed as of SDL 2.0.2.")
+  elseif(CMAKE_SYSTEM_NAME MATCHES "Haiku.*")
+    set(SDL_CMAKE_PLATFORM HAIKU)
+  elseif(NINTENDO_3DS)
+    set(SDL_CMAKE_PLATFORM N3DS)
+  elseif(OS2)
+    set(SDL_CMAKE_PLATFORM OS2)
+  endif()
+  if(SDL_CMAKE_PLATFORM)
+    set(${SDL_CMAKE_PLATFORM} TRUE)
+  endif()
+endmacro()